packages: Add xone

nix/override/cambalache.nix

@@ -0,0 +1,92 @@
+{ stdenv
+, lib
+, pkgs
+, fetchFromGitLab
+, nix-update-script
+}:
+
+pkgs.python3.pkgs.buildPythonApplication rec {
+  pname = "cambalache";
+  version = "0.90.1";
+
+  format = "other";
+
+  # Did not fetch submodule since it is only for tests we don't run.
+  src = fetchFromGitLab {
+    domain = "gitlab.gnome.org";
+    owner = "jpu";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-YuRxqrGJvhMMZApD/tQSWkUg/nZnp/xryBJSjXCXO4w=";
+  };
+
+  nativeBuildInputs = with pkgs; [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection # for setup hook
+    desktop-file-utils # for update-desktop-database
+    shared-mime-info # for update-mime-database
+    wrapGAppsHook
+  ];
+
+  pythonPath = with pkgs.python3.pkgs; [
+    pygobject3
+    lxml
+  ];
+
+  buildInputs = with pkgs; [
+    glib
+    gtk3
+    gtk4
+    gtksourceview4
+    gtksourceview5
+    webkitgtk_4_1
+    webkitgtk_6_0
+    # For extra widgets support.
+    libadwaita
+    libhandy
+  ];
+
+  # Prevent double wrapping.
+  dontWrapGApps = true;
+
+  postPatch = ''
+    patchShebangs postinstall.py
+    # those programs are used at runtime not build time
+    # https://gitlab.gnome.org/jpu/cambalache/-/blob/0.12.1/meson.build#L79-80
+    substituteInPlace ./meson.build \
+      --replace "find_program('broadwayd', required: true)" "" \
+      --replace "find_program('gtk4-broadwayd', required: true)" ""
+  '';
+
+  preFixup = ''
+    # Let python wrapper use GNOME flags.
+    makeWrapperArgs+=(
+      # For broadway daemons
+      --prefix PATH : "${lib.makeBinPath [ pkgs.gtk3 pkgs.gtk4 ]}"
+      "''${gappsWrapperArgs[@]}"
+    )
+  '';
+
+  postFixup = ''
+    # Wrap a helper script in an unusual location.
+    wrapPythonProgramsIn "$out/${pkgs.python3.sitePackages}/cambalache/priv/merengue" "$out $pythonPath"
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = with lib; {
+    homepage = "https://gitlab.gnome.org/jpu/cambalache";
+    description = "RAD tool for GTK 4 and 3 with data model first philosophy";
+    mainProgram = "cambalache";
+    maintainers = teams.gnome.members;
+    license = with licenses; [
+      lgpl21Only # Cambalache
+      gpl2Only # tools
+    ];
+    platforms = platforms.unix;
+  };
+}

nix/override/oxicalc.nix

@@ -32,7 +32,6 @@ rustPlatform.buildRustPackage rec {
     libadwaita
   ];
 
-
   postInstall = ''
     	install -D --mode=444 $src/${pname}.desktop $out/share/applications/${pname}.desktop
     	install -D --mode=444 $src/${pname}.svg $out/share/pixmaps/${pname}.svg

nix/override/reset.nix

@@ -0,0 +1,53 @@
+{ pkgs
+, lib
+, fetchFromGitHub
+}:
+let
+  toolchain = pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.minimal);
+  rustPlatform = pkgs.makeRustPlatform {
+    cargo = toolchain;
+    rustc = toolchain;
+  };
+in
+rustPlatform.buildRustPackage rec {
+  pname = "reset";
+  version = "1.1.1";
+
+  src = fetchFromGitHub {
+    owner = "Xetibo";
+    repo = "ReSet";
+    rev = "${version}";
+    hash = "sha256-nyEGhD4IlsJ1AqRZC7aP2vOuq4etvZ7BwTMxb4u7cxY=";
+  };
+
+  cargoHash = "sha256-lcNu8yEQiSTshXCwblBLYpSJWmErS53z+SviqaqlSnI=";
+
+  nativeBuildInputs = with pkgs;[
+    pkg-config
+    glib
+    wrapGAppsHook4
+  ];
+
+  buildInputs = with pkgs;[
+    gtk4
+    libadwaita
+    pulseaudio
+    dbus
+    gdk-pixbuf
+    gnome.adwaita-icon-theme
+  ];
+
+  postInstall = ''
+    	install -D --mode=444 $src/${pname}.desktop $out/share/applications/${pname}.desktop
+    	install -D --mode=444 $src/src/resources/icons/ReSet.svg $out/share/pixmaps/ReSet.svg
+  '';
+
+  meta = with lib; {
+    description = "";
+    homepage = "https://github.com/Xetibo/ReSet";
+    changelog = "https://github.com/Xetibo/ReSet/releases/tag/${version}";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ DashieTM ];
+    mainProgram = "reset";
+  };
+}